. 神仙醋°男孩

asp读写文件的函数和实例

当前位置:新空网络工作室 > 论坛交流 > 列表
发表时间 2018/9/4 23:39:02
楼主
<%
'*********************************************
'函数:WriteFileTo
'作用:生成文件
'备注:ConTentStr(内容) PathStr(路径) CharsetStr(编码)
'*********************************************
Function WriteFileTo(ByVal PathStr,ByVal ConTentStr,ByVal CharsetStr)
    Dim objStream
    Set objStream = Server.CreateObject("ADODB.Stream")
    With objStream
    .Open
    .Charset   = CharsetStr
    .Position  = objStream.Size
    .WriteText = ConTentStr
    .SaveToFile Server.Mappath(PathStr), 2
    .Close
    End With
    Set objStream = Nothing 
End Function
'*********************************************
'函数:ReadFileFrom
'作用:读取文件
'备注:PathStr(路径) CharsetStr(编码)
'*********************************************
Function ReadFileFrom(ByVal PathStr,ByVal CharsetStr)
    Dim ConTentStr,objStream
    Set objStream = Server.CreateObject("ADODB.Stream")
    With objStream
    .Type = 2
    .Mode = 3
    .Charset = CharsetStr
    .Open
    .LoadFromFile Server.MapPath(PathStr)
    ConTentStr = .ReadText
    End With
    Set objStream = Nothing 
    ReadFileFrom = ConTentStr
End Function
%>
<%
'------读取模版内容
ConTent=ReadFileFrom("Html/Template_Show.Html","utf-8")
'------替换模版标签
ConTent=Replace(ConTent,"{Title}","标题")
ConTent=Replace(ConTent,"{ConTent}","内容")
'------生成文件名字
PathStr="Html/Show_1"&".Html"
'------开始生成文件
Call WriteFileTo(PathStr,ConTent,"utf-8")
Response.Write ("成功生成文件"&"<a href='" & PathStr & "'>" & PathStr & "<a>")
%>


. 您还没有登录
保存远程图片到论坛